# WENN-Funktion (IF)

> WENN prüft eine Bedingung und gibt einen Wert zurück, wenn sie erfüllt ist, und einen anderen, wenn nicht.

Quelle: https://spreadsheetpractice.com/de/funktionen/wenn · Aktualisiert 29. Oktober 2026 · Geprüft durch Ausführen: Unsere Formel-Engine hat alle Formeln auf dieser Seite berechnet am 30. Oktober 2026

## Kurz gesagt

- **Syntax:** `=WENN(Prüfung; Dann_Wert; [Sonst_Wert])`
- **Häufigste Verwendung:** `=WENN(B2>=200;"Versandkostenfrei";"Standard")` ergibt Versandkostenfrei (Ein Textergebnis abhängig von einer Zahlenprüfung)
- **Englischer Name:** [IF](https://spreadsheetpractice.com/functions/if)
- **Verfügbar in:** Alle aktuellen Versionen
- **Kategorie:** [Logik](https://spreadsheetpractice.com/de/funktionen#logic)
- **Rückgabewert:** Den Wert, der zum Ergebnis der Prüfung passt.
- **Google Sheets:** Funktioniert in Google Sheets genauso.

Die Funktion ist der Grundbaustein für Kennzeichen, Staffeln, Boni und jede Regel, die sich als „wenn das, dann dies“ formulieren lässt. Kombiniere sie mit UND oder ODER für mehrere Bedingungen, oder wechsle zu WENNS, wenn es mehr als zwei Ergebnisse gibt.

## Syntax

`=WENN(Prüfung; Dann_Wert; [Sonst_Wert])`

Im deutschen Excel werden Argumente mit Semikolon (;) getrennt, und Dezimalzahlen haben ein Komma.

| Argument | Erforderlich? | Bedeutung |
|---|---|---|
| `Prüfung` | Erforderlich | Ein Vergleich, der WAHR oder FALSCH ergibt, etwa B2>=100 oder C2="Bezahlt". |
| `Dann_Wert` | Erforderlich | Was zurückgegeben wird, wenn die Prüfung WAHR ist: eine Zahl, Text in Anführungszeichen, eine Zelle oder eine andere Formel. |
| `Sonst_Wert` | Optional | Was zurückgegeben wird, wenn die Prüfung FALSCH ist. Fehlt das Argument, liefert WENN den Wert FALSCH. |

## Beispiele

Jedes Ergebnis wird von unserer Formel-Engine aus der Beispieltabelle berechnet, derselben, die auch die Übungen prüft.

| Zelle | Formel | Ergebnis | Was es zeigt |
|---|---|---|---|
| E2 | `=WENN(B2>=200;"Versandkostenfrei";"Standard")` | Versandkostenfrei | Ein Textergebnis abhängig von einer Zahlenprüfung |
| E3 | `=WENN(C3="Nein";B3*0,05;0)` | 4,25 € | Eine Berechnung, wenn die Prüfung WAHR ist: 5 % Säumniszuschlag auf eine unbezahlte Bestellung |
| E4 | `=WENN(UND(B4>500;C4="Nein");"Kunden anrufen";"")` | Kunden anrufen | Zwei Bedingungen mit UND; "" lässt die Zelle leer, wenn die Prüfung nicht erfüllt ist |

### Beispieldaten als Tabelle anzeigen

|  | A | B | C | D | E |
|---|---|---|---|---|---|
| 1 | Bestellung | Summe | Bezahlt |  | Ergebnis |
| 2 | SO-1001 | 240 € | Ja |  | Versandkostenfrei |
| 3 | SO-1002 | 85 € | Nein |  | 4,25 € |
| 4 | SO-1003 | 510 € | Nein |  | Kunden anrufen |
| 5 | SO-1004 | 130 € | Ja |  |  |

## Typische Fehler

| Was du siehst | Ursache und Lösung |
|---|---|
| #NAME? | Textergebnisse brauchen doppelte Anführungszeichen: "Ja", nicht Ja. Ohne sie sucht Excel nach einem Namen, der Ja heißt. |
| Eine Prüfung, die passen müsste, passt nicht | C2="Ja" ergibt FALSCH, wenn in der Zelle "Ja " mit einem Leerzeichen am Ende steht. Bereinige die Spalte mit GLÄTTEN oder prüfe =GLÄTTEN(C2)="Ja". |
| Staffeln in der falschen Reihenfolge | Prüfe in verschachtelten WENN-Funktionen zuerst die höchste Schwelle: =WENN(B2>=1000;"Gold";WENN(B2>=500;"Silber";"Bronze")). Prüfst du zuerst >=500, landet jeder Kunde ab 1.000 bei Silber. |
| Ein Bereich wie in der Mathematik geschrieben | =WENN(10<B2<20;…) ist in Excel immer FALSCH. Teile den Vergleich auf: =WENN(UND(B2>10;B2<20);…). |

## Tipps

- Gib "" zurück, um eine leere Zelle statt 0 oder FALSCH anzuzeigen.
- Vergleiche mit einer Zelle, etwa B2>=$H$1, statt die Schwelle in die Formel zu tippen, dann änderst du sie an einer einzigen Stelle.

## Verwandte Funktionen

- [WENNS](https://spreadsheetpractice.com/de/funktionen/wenns) (IFS): WENNS prüft eine Liste von Bedingungen der Reihe nach und gibt den Wert zurück, der zur ersten WAHREN Bedingung gehört.
- [ERSTERWERT](https://spreadsheetpractice.com/de/funktionen/ersterwert) (SWITCH): ERSTERWERT vergleicht einen Wert mit einer Liste exakter Treffer und gibt das Ergebnis zurück, das zum ersten Treffer gehört, optional mit einem Standardwert am Ende.
- [UND](https://spreadsheetpractice.com/de/funktionen/und) (AND): UND gibt nur dann WAHR zurück, wenn alle angegebenen Bedingungen WAHR sind.
- [ODER](https://spreadsheetpractice.com/de/funktionen/oder) (OR): ODER gibt WAHR zurück, sobald mindestens eine der Bedingungen WAHR ist.
- [WENNFEHLER](https://spreadsheetpractice.com/de/funktionen/wennfehler) (IFERROR): WENNFEHLER gibt einen selbst gewählten Wert zurück, wenn eine Formel einen Fehler ergibt, und sonst das normale Ergebnis der Formel.

## Häufige Fragen

### Wie viele WENN-Funktionen kann man in Excel verschachteln?

Bis zu 64, aber mehr als drei oder vier lassen sich kaum noch prüfen. Nimm stattdessen WENNS, ERSTERWERT oder einen XVERWEIS auf eine kleine Tabelle.

### Wie verwende ich WENN mit zwei Bedingungen?

Setze UND oder ODER in die Prüfung: =WENN(UND(B2>100;C2="Bezahlt");"OK";"Prüfen") verlangt beide Bedingungen, bei ODER reicht eine.

### Warum gibt meine WENN-Formel FALSCH zurück?

Die Prüfung war FALSCH, und Sonst_Wert fehlt. Gib ein drittes Argument an, etwa "" für eine leere Zelle.

## WENN üben

Auf der Seite zu [WENN](https://spreadsheetpractice.com/de/funktionen/wenn) gibt es eine Übung („Bestanden oder nicht“), die du löst, indem du die Formel auf Deutsch mit Semikolon eingibst. Sie wird sofort geprüft und danach mit geänderten Daten noch einmal.

Diese Seite auf Englisch: [IF](https://spreadsheetpractice.com/functions/if)

[Excel-Funktionsübersetzer](https://spreadsheetpractice.com/tools/function-translator): Funktionsnamen in 8 Sprachen

[Alle Funktionen auf Deutsch](https://spreadsheetpractice.com/de/funktionen)

---

Spreadsheet Practice (https://spreadsheetpractice.com) bringt Tabellenformeln durch Üben bei: Jede Übung wird in einem Live-Raster geprüft und mit geänderten Daten noch einmal kontrolliert.